build.gradle

buildscript {
    // Build-time only: the Shadow 8.1.1 Gradle plugin pulls vulnerable transitive deps onto
    // the plugin (buildscript) classpath. These run only in the Gradle build JVM and are NOT
    // part of the published artifact, but we still pin them to patched versions to clear the
    // Dependabot alerts:
    //   - commons-io 2.11.0  -> CVE-2024-47554  (fixed in 2.14.0)
    //   - plexus-utils 3.5.1 -> CVE-2025-67030  (fixed in 3.6.1)
    //   - log4j 2.20.0       -> CVE-2026-49844  (fixed in 2.25.5)
    configurations.classpath {
        resolutionStrategy {
            force 'commons-io:commons-io:2.18.0'
            force 'org.codehaus.plexus:plexus-utils:3.6.1'
            force 'org.apache.logging.log4j:log4j-api:2.25.5'
            force 'org.apache.logging.log4j:log4j-core:2.25.5'
        }
    }
}

plugins {
    id 'com.github.johnrengelman.shadow' version '8.1.1'
    id 'java-library'
    id 'maven-publish'
    id 'signing'
    id 'idea'
    id "io.github.gradle-nexus.publish-plugin" version '1.1.0'
}

group = 'io.pinecone'
version = pineconeClientVersion // [pc:VERSION_NEXT]
description = 'The Pinecone.io Java Client'

sourceCompatibility = JavaVersion.VERSION_1_8

repositories {
    mavenCentral()
    jcenter()
}

sourceSets {
    main {
        java {
            srcDirs 'build/generated/source/proto/main/grpc'
            srcDirs 'build/generated/source/proto/main/java'
        }
    }

    integrationTest {
        java {
            compileClasspath += main.output + test.output
            runtimeClasspath += main.output + test.output
            srcDir file('src/integration/java')
        }
        resources.srcDir file('src/integration/resources')
    }
}

def grpcVersion = '1.60.2'
// Netty is pulled in transitively by grpc-netty (1.60.2 -> 4.1.100.Final, which is vulnerable
// to CVE-2025-24970). grpc-netty does not pin a patched Netty even in recent releases, so we
// pin Netty directly here. Bump alongside grpc when grpc itself ships a patched Netty.
// Stay on the 4.1.x line: grpc-netty 1.60.2 targets Netty 4.1 and 4.2 changed the buffer
// allocator and IoHandler APIs it depends on.
def nettyVersion = '4.1.136.Final'

dependencies {
    api "io.grpc:grpc-protobuf:${grpcVersion}"
    api "io.grpc:grpc-stub:${grpcVersion}"
    api "io.grpc:grpc-netty:${grpcVersion}"
    // Pin every Netty module that grpc-netty declares directly so the patched version wins
    // transitive resolution for consumers too (Maven nearest-wins / Gradle highest-wins).
    // Fixes CVE-2025-24970 (netty-handler/netty-common, HIGH) and pulls in the patched
    // netty-codec-http (CVE-2024-29025) and netty-common (CVE-2025-25193).
    api "io.netty:netty-codec-http2:${nettyVersion}"
    api "io.netty:netty-handler-proxy:${nettyVersion}"
    api "io.netty:netty-transport-native-unix-common:${nettyVersion}"
    runtimeOnly 'io.netty:netty-tcnative-boringssl-static:2.0.77.Final'
    implementation 'org.slf4j:slf4j-api:2.0.5'
    implementation 'com.google.api.grpc:proto-google-common-protos:2.14.3'
    implementation 'com.squareup.okhttp3:okhttp:4.12.0'
    implementation 'com.squareup.okhttp3:logging-interceptor:4.12.0'
    implementation 'com.fasterxml.jackson.core:jackson-databind:2.21.5'
    implementation 'com.fasterxml.jackson.core:jackson-core:2.21.5'
    implementation 'com.google.code.gson:gson:2.9.1'
    implementation 'io.gsonfire:gson-fire:1.8.5'
    implementation 'org.openapitools:jackson-databind-nullable:0.2.6'
    implementation 'com.google.protobuf:protobuf-java:4.29.3'
    compileOnly "org.apache.tomcat:annotations-api:6.0.53" // necessary for Java 9+

    testImplementation("com.squareup.okhttp3:mockwebserver:4.12.0")
    testImplementation "io.grpc:grpc-testing:${grpcVersion}"
    testImplementation "org.hamcrest:hamcrest:2.2"
    testImplementation 'org.mockito:mockito-inline:4.8.0'
    testImplementation 'org.slf4j:slf4j-simple:2.0.5'
    testImplementation 'com.fasterxml.jackson.core:jackson-databind:2.21.5'
    testImplementation 'org.junit.jupiter:junit-jupiter-api:5.8.0'
    testImplementation 'org.junit.platform:junit-platform-launcher:1.8.0'
    testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.8.0'
}

import org.gradle.api.tasks.testing.logging.TestExceptionFormat
import org.gradle.api.tasks.testing.logging.TestLogEvent

tasks.withType(Test) {
    systemProperty "net.bytebuddy.experimental", "true"
    testLogging {
        // set options for log level LIFECYCLE
        events TestLogEvent.FAILED,
                TestLogEvent.PASSED,
                TestLogEvent.SKIPPED,
                TestLogEvent.STANDARD_OUT
        exceptionFormat TestExceptionFormat.FULL
        showExceptions true
        showCauses true
        showStackTraces true

        // set options for log level DEBUG and INFO
        debug {
            events TestLogEvent.STARTED,
                    TestLogEvent.FAILED,
                    TestLogEvent.PASSED,
                    TestLogEvent.SKIPPED,
                    TestLogEvent.STANDARD_ERROR,
                    TestLogEvent.STANDARD_OUT
            exceptionFormat TestExceptionFormat.FULL
        }
        info.events = debug.events
        info.exceptionFormat = debug.exceptionFormat

        afterSuite { desc, result ->
            if (!desc.parent) { // will match the outermost suite
                def output = "Results: ${result.resultType} (${result.testCount} tests, ${result.successfulTestCount} passed, ${result.failedTestCount} failed, ${result.skippedTestCount} skipped)"
                def startItem = '|  ', endItem = '  |'
                def repeatLength = startItem.length() + output.length() + endItem.length()
                println('\n' + ('-' * repeatLength) + '\n' + startItem + output + endItem + '\n' + ('-' * repeatLength))
            }
        }
    }
}

javadoc {
    options.tags = [ "http.response.details:a:Http Response Details" ]
    options.addStringOption('Xdoclint:none', '-quiet')
}

tasks.register('generateJavadoc', Javadoc) {
    source = sourceSets.main.allJava
    classpath += configurations.runtimeClasspath
    options.addStringOption('tag', 'http.response.details:a:Http Response Details')
    options.memberLevel = JavadocMemberLevel.PUBLIC
    destinationDir = file("${projectDir}/docs")
}

configurations {
    integrationTestImplementation.extendsFrom testImplementation
    integrationTestRuntimeOnly.extendsFrom testRuntimeOnly
}

java {
    withSourcesJar()
    withJavadocJar()
}

tasks.named('jar') {
    manifest {
        attributes('Implementation-Title': project.name,
                'Implementation-Version': project.version)
    }
}

tasks.named('build') {
    dependsOn('shadowJar')
}

test {
    useJUnitPlatform()
}

task integrationTest(type: Test) {
    useJUnitPlatform()
    testClassesDirs = sourceSets.integrationTest.output.classesDirs
    classpath = sourceSets.integrationTest.runtimeClasspath
    outputs.upToDateWhen { false }
}

// Configure Shadow JAR with relocations and transformers
import com.github.jengelman.gradle.plugins.shadow.transformers.ServiceFileTransformer

shadowJar {
    // jackson-core (2.15+) is a multi-release JAR that bundles Java 21 (class-file major 65)
    // variants under META-INF/versions/21. The Shadow 8.1.1 plugin relocates com.fasterxml
    // and its ASM cannot read major version 65, so it fails with
    // "Unsupported class file major version 65". These are JDK-21-only optimizations; dropping
    // them is safe because the base (Java 8) classes remain and multi-release fallback applies.
    exclude 'META-INF/versions/21/**'
    relocate 'io.grpc', 'io.pinecone.shadow.io.grpc'
    relocate 'com.google', 'io.pinecone.shadow.com.google'
    relocate 'org.slf4j', 'io.pinecone.shadow.org.slf4j'
    relocate 'okhttp3', 'io.pinecone.shadow.okhttp3'
    relocate 'okio', 'io.pinecone.shadow.okio'
    relocate 'com.fasterxml', 'io.pinecone.shadow.com.fasterxml'
    relocate 'com.google.gson', 'io.pinecone.shadow.com.google.gson'
    relocate 'io.gsonfire', 'io.pinecone.shadow.io.gsonfire'
    relocate 'org.openapitools', 'io.pinecone.shadow.org.openapitools'
    relocate 'com.google.protobuf', 'io.pinecone.shadow.com.google.protobuf'
    relocate 'org.apache.tomcat', 'io.pinecone.shadow.org.apache.tomcat'
    transform(ServiceFileTransformer)
}

publishing {
    publications {
        pineconeClientMaven(MavenPublication) {
            from components.java
            pom {
                artifactId = 'pinecone-client'
                name = 'pinecone-client'
                description = 'The Pinecone.io Java Client'
                url = 'https://github.com/pinecone-io/pinecone-java-client'
                licenses {
                    license {
                        name = 'The Apache License, Version 2.0'
                        url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                        distribution = 'repo'
                    }
                }
                developers {
                    developer {
                        id = 'pinecone-ops'
                        name = 'Pinecone.io Ops'
                        email = 'ops@pinecone.io'
                    }
                }
                scm {
                    connection = 'scm:git:git://github.com/pinecone-io/pinecone-java-client.git'
                    developerConnection = 'scm:git:ssh://github.com/pinecone-io/pinecone-java-client.git'
                    url = 'http://github.com/pinecone-io/pinecone-java-client'
                }
            }
        }
    }

    publications {
        mavenJava(MavenPublication) {
            from components.java
            pom {
                artifactId = 'pinecone-client'
                name = 'pinecone-client'
                description = 'The Pinecone.io Java Client'
            }
        }
    }
    repositories {
        mavenLocal()
    }
}

nexusPublishing {
    repositories {
        sonatype {
            nexusUrl.set(uri("https://ossrh-staging-api.central.sonatype.com/service/local/"))
            snapshotRepositoryUrl.set(uri("https://central.sonatype.com/repository/maven-snapshots/"))
        }
    }
}

signing {
    def signingKeyId = findProperty("signingKeyId")
    def signingKey = findProperty("signingKey")
    def signingPassword = findProperty("signingPassword")
    useInMemoryPgpKeys(signingKeyId, signingKey, signingPassword)
    sign publishing.publications.pineconeClientMaven
}