Adapt/settings.gradle at master · VolmitSoftware/Adapt · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
import java.io.File

rootProject.name = 'Adapt'

boolean hasVolmLibSettings(File directory) {
    new File(directory, 'settings.gradle.kts').exists() || new File(directory, 'settings.gradle').exists()
}

File resolveLocalVolmLibDirectory() {
    String configuredPath = providers.gradleProperty('localVolmLibDirectory')
        .orElse(providers.environmentVariable('VOLMLIB_DIR'))
        .orNull
    if (configuredPath != null && !configuredPath.isBlank()) {
        File configuredDirectory = file(configuredPath)
        if (hasVolmLibSettings(configuredDirectory)) {
            return configuredDirectory
        }
    }

    File currentDirectory = settingsDir
    while (currentDirectory != null) {
        File candidate = new File(currentDirectory, 'VolmLib')
        if (hasVolmLibSettings(candidate)) {
            return candidate
        }

        currentDirectory = currentDirectory.parentFile
    }

    null
}

boolean useLocalVolmLib = providers.gradleProperty('useLocalVolmLib')
    .orElse('true')
    .map { String value -> value.equalsIgnoreCase('true') }
    .get()
File localVolmLibDirectory = resolveLocalVolmLibDirectory()

if (useLocalVolmLib && localVolmLibDirectory != null) {
    includeBuild(localVolmLibDirectory) {
        dependencySubstitution {
            substitute(module('com.github.VolmitSoftware:VolmLib')).using(project(':shared'))
            substitute(module('com.github.VolmitSoftware.VolmLib:shared')).using(project(':shared'))
            substitute(module('com.github.VolmitSoftware.VolmLib:packaging')).using(project(':packaging'))
            substitute(module('com.github.VolmitSoftware.VolmLib:native-api')).using(project(':native-api'))
            substitute(module('com.github.VolmitSoftware.VolmLib:native-terrain-api')).using(project(':native-terrain-api'))
            substitute(module('com.github.VolmitSoftware.VolmLib:native-common')).using(project(':native-common'))
            substitute(module('com.github.VolmitSoftware.VolmLib:native-minecraft26_2-sources')).using(project(':native-minecraft26_2-sources'))
            substitute(module('com.github.VolmitSoftware.VolmLib:native-v26_2_R1')).using(project(':native:v26_2_R1'))
            substitute(module('com.github.VolmitSoftware.VolmLib:native-v26_3_R1')).using(project(':native:v26_3_R1'))
            substitute(module('com.github.VolmitSoftware.VolmLib:volmlib-shared')).using(project(':shared'))
        }
    }
}

File resolveLocalHiddenOreDirectory() {
    String configuredPath = providers.gradleProperty('localHiddenOreDirectory')
        .orElse(providers.environmentVariable('HIDDENORE_DIR'))
        .orNull
    if (configuredPath != null && !configuredPath.isBlank()) {
        File configuredDirectory = file(configuredPath)
        if (hasVolmLibSettings(configuredDirectory)) {
            return configuredDirectory
        }
    }

    File currentDirectory = settingsDir
    while (currentDirectory != null) {
        File candidate = new File(currentDirectory, 'HiddenOre')
        if (hasVolmLibSettings(candidate)) {
            return candidate
        }

        currentDirectory = currentDirectory.parentFile
    }

    null
}

boolean useLocalHiddenOre = providers.gradleProperty('useLocalHiddenOre')
    .orElse('true')
    .map { String value -> value.equalsIgnoreCase('true') }
    .get()
File localHiddenOreDirectory = resolveLocalHiddenOreDirectory()

if (useLocalHiddenOre && localHiddenOreDirectory != null) {
    includeBuild(localHiddenOreDirectory) {
        dependencySubstitution {
            substitute(module('com.github.VolmitSoftware:HiddenOre')).using(project(':'))
        }
    }
}

File resolveLocalIrisDirectory() {
    String configuredPath = providers.gradleProperty('localIrisDirectory')
        .orElse(providers.environmentVariable('IRIS_DIR'))
        .orNull
    if (configuredPath != null && !configuredPath.isBlank()) {
        File configuredDirectory = file(configuredPath)
        if (hasVolmLibSettings(configuredDirectory)) {
            return configuredDirectory
        }
    }

    File currentDirectory = settingsDir
    while (currentDirectory != null) {
        File candidate = new File(currentDirectory, 'Iris')
        if (hasVolmLibSettings(candidate)) {
            return candidate
        }

        currentDirectory = currentDirectory.parentFile
    }

    null
}

boolean useLocalIris = providers.gradleProperty('useLocalIris')
    .orElse('true')
    .map { String value -> value.equalsIgnoreCase('true') }
    .get()
File localIrisDirectory = resolveLocalIrisDirectory()

if (useLocalIris && localIrisDirectory != null) {
    includeBuild(localIrisDirectory) {
        dependencySubstitution {
            substitute(module('com.github.VolmitSoftware:Iris')).using(project(':adapters:bukkit:plugin'))
        }
    }
}